extends SceneTree
func _initialize() -> void:
	call_deferred("run")
func run() -> void:
	for id: String in ["ak47","ppsh41","sks","makarov","tokarev"]:
		var source := (load("res://assets/soviet/%s.glb" % id) as PackedScene).instantiate() as Node3D
		root.add_child(source)
		var bounds := AABB()
		var first := true
		for mesh: MeshInstance3D in source.find_children("*","MeshInstance3D",true,false):
			var box := mesh.global_transform*mesh.mesh.get_aabb()
			bounds = box if first else bounds.merge(box)
			first = false
		var length: float = {"ak47":0.88,"ppsh41":0.84,"sks":1.02,"makarov":0.23,"tokarev":0.25}[id]
		var scale_factor := length/bounds.size.z
		var rear := 0.30 if length > 0.5 else 0.07
		var shift := Vector3(0,-bounds.end.y*scale_factor+0.065,rear-bounds.end.z*scale_factor)
		var model := Node3D.new()
		for part: String in ["Frame","Magazine","Bolt"]:
			var group := Node3D.new()
			group.name = part
			model.add_child(group)
			group.owner = model
		var receiver := Node3D.new()
		receiver.name = "receiver"
		model.get_node("Frame").add_child(receiver)
		receiver.owner = model
		for mesh: MeshInstance3D in source.find_children("*","MeshInstance3D",true,false):
			var copy := MeshInstance3D.new()
			copy.name = mesh.name
			copy.mesh = mesh.mesh
			copy.transform = Transform3D(Basis.IDENTITY.scaled(Vector3.ONE*scale_factor),shift)*mesh.global_transform
			var group: Node = model.get_node("Magazine") if mesh.name == "mag" else (model.get_node("Bolt") if mesh.name in ["slide","charger","charging_handle"] else receiver)
			group.add_child(copy)
			copy.owner = model
			for surface in mesh.mesh.get_surface_count():
				var material := mesh.get_active_material(surface).duplicate() as StandardMaterial3D
				material.texture_filter = BaseMaterial3D.TEXTURE_FILTER_LINEAR_WITH_MIPMAPS_ANISOTROPIC
				material.roughness = 0.72
				var path := "res://assets/soviet/%s_%s_%s.tres" % [id,mesh.name,surface]
				ResourceSaver.save(material,path)
				copy.set_surface_override_material(surface,load(path))
				if mesh.mesh.get_surface_count() == 1: copy.material_override = load(path)
		var muzzle := Marker3D.new()
		muzzle.name = "Muzzle"
		muzzle.position = Vector3(0,0.016,rear-length)
		model.add_child(muzzle)
		muzzle.owner = model
		var packed := PackedScene.new()
		packed.pack(model)
		ResourceSaver.save(packed,"res://assets/soviet/%s.tscn" % id)
		model.free()
		source.free()
	quit()